ToneScript

ToneScript is a description syntax for the characteristics of call-progress tones. A call progress tone is a pattern of audible tones played to the caller in a telephone call, conveying the status of the call. ToneScript describes the pattern of frequency, cadence, and level of the signal. Many Internet telephony devices support configuration options for users to customize the tones, but standard patterns are provided for various telephone administrations. ToneScript is used in Sipura, Linksys and Cisco family of IP telephony products.

## Contents

* 1 Format
* 2 Examples
* 3 North American tones
* 4 Australian tones
* 5 Ireland tones
* 6 References
* 7 External links

## Format

* A ToneScript syntax may have at most 120 characters.
* A calling tone may use up to 6 frequency components nk where 1<=k<=6
* A cadence section Zi indicates its Duration Di followed by up to 6 subsections ZZi,j in parentheses. A subsection consists of an ON duration (* for always on), an OFF duration and the list of frequency components fi,j used in that subsection.

fi,j:=n1[+n2[+n3[+n4[+n5[+n6]]]]]
ZZi,j:=oni,j/offi,j/fi,j
Zi:=Di([ZZi,1[,ZZi,2[,ZZi,3[,ZZi,4[,ZZi,5[,ZZi,6]]]]])

* A FreqScript is a sequence of frequencies Fi in hertz and their corresponding levels Li in dBm

FreqScript:=F1@L1[,F2@L2]
* A Tone Script has a frequency specification and one or two cadence sections.

ToneScript:=FreqScript;Z1[;Z2]

## Examples

* 350@-19,440@-19;10(*/0/1+2)

Contains 2 frequency components

Frequency component 1 is 350 Hz at -19 dBm
Frequency component 2 is 440 Hz at -19 dBm
There is 1 Cadence Section

In this section, The duration is 10 seconds and the tone has only 1 subsections

In the only subsection the tone is always on, off for 0 seconds, and composed of both the Frequency components 1 and 2 (350 Hz and 440 Hz)
* 350@-19,440@-19;2(.2/.2/1+2);10(*/0/1+2)

Contains 2 frequency components

Frequency component 1 is 350 Hz at -19 dBm
Frequency component 2 is 440 Hz at -19 dBm
There are two Cadence Sections

In the first Cadence Section, The duration is 2 seconds and the tone has only 1 subsections

In the only subsection the tone is on for 0.2 seconds, off for 0.2 seconds, and composed of both the Frequency components 1 and 2 (350 Hz and 440 Hz)
In the second Cadence Section, The duration is 10 seconds and again the tone has only 1 subsections

In the only subsection the tone is always on, off for 0 seconds, and composed of both the Frequency components 1 and 2 (350 Hz and 440 Hz)
* 349@-21,392@-21,440@-21,466@-21,523@-24,540@-24;2.1(.6/0/3,.2/0/2,.7/0/1,.2/0/2,.2/0/3,.3/0/4);30(*/0/5+6)

Christmas theme dialtone (seven notes of ′The First Noel′ then continuous dialtone for 30 seconds)
Contains 6 frequency components

Frequency components are 349, 392, 440, 466, 523 and 540 Hz (five musical notes) plus a beat frequency tone mix to give a warble dialtone beat thereafter.
There are two Cadence Sections

In the first Cadence Section, the total duration is 2.1 seconds and the tone has 6 subsections with timing set for music.

The tones are turned on and off to give the ′notes′ of the familiar Christmas carol.
In the second Cadence Section, the duration is 30 seconds. It combines tones 5 and 6 to give the last note and the familiar 17 Hz beat of dialtone.

* 392@-19,440@-19,494@-19,294@-19,457@-19;3.5(.7/0/4,.8/0/1,.6/0/1,.5/0/3,.7/0/2,.2/0/1);30(*/0/2+5)

New Year theme dialtone (four notes of ′Auld Lang Syne′ then continuous dialtone for 30 seconds)
Contains 5 frequency components

Frequency components are 392, 440, 494, 292 and 457 Hz (four musical notes) plus a beat frequency tone mix to give a warble dialtone beat thereafter.
There are two Cadence Sections

In the first Cadence Section, the total duration is 3.5 seconds and the tone has 6 subsections with timing set for music.

The tones are turned on and off to give the ′notes′ of the familiar New Year's Eve tune.
In the second Cadence Section, the duration is 30 seconds. It combines tones 4 and 5 to give the last note in the familiar 17 Hz beat of dialtone.

## North American tones

Name | ToneScript

|

Dial tone | 350@-19,440@-19;10(*/0/1+2)
Second dial tone  | 350@-19,440@-19;10(*/0/1+2)
Outside dial tone  | 450@-19,550@-19;10(*/0/1+2)
Prompt tone  | 520@-19,620@-19;10(*/0/1+2)
Busy tone  | 480@-19,620@-19;10(.5/.5/1+2)
Reorder tone  | 480@-19,620@-19;10(.25/.25/1+2)
Howler/off-hook warning tone  | 480@-10,620@0;10(.125/.125/1+2)
Audible ringing  | 440@-19,480@-19;*(2/4/1+2)
Confirm tone  | 600@-16;1(.25/.25/1)
Special information tone SIT1  | 985@-16,1428@-16,1777@-16;20(.380/0/1,.380/0/2,.380/0/3,0/4/0)
Special information tone SIT2  | 914@-16,1371@-16,1777@-16;20(.274/0/1,.274/0/2,.380/0/3,0/4/0)
Special information tone SIT3  | 914@-16,1371@-16,1777@-16;20(.380/0/1,.380/0/2,.380/0/3,0/4/0)
Special information tone SIT4  | 985@-16,1371@-16,1777@-16;20(.380/0/1,.274/0/2,.380/0/3,0/4/0)
MWI dial tone  | 350@-19,440@-19;2(.1/.1/1+2);10(*/0/1+2)
Call forward dial tone  | 350@-19,440@-19;2(.2/.2/1+2);10(*/0/1+2)
Holding tone  | 600@-19;*(.1/.1/1,.1/.1/1,.1/9.5/1)
Conference call tone  | 350@-19;20(.1/.1/1,.1/9.7/1)
Call waiting tone  | 440@-10;30(.3/9.7/1)

## Australian tones

Name | ToneScript

|

Dial tone | 400@-19,425@-19;10(*/0/1+2)
Busy tone  | 425@-19;10(.375/.375/1)
Reorder tone  | 425@-19,425@-29;60(.375/.375/1,.375/.375/2)
Ringback tone  | 413@-19,438@-19,0@-19;*(.4/.2/1+2,.4/.2/1+2,0/2/3)
Confirm tone  | 425@-16;2(1/1/1)
MWI dial tone  | 400@-19,425@-19;10(.100/.040/1+2)
Cfwd dial tone  | 425@-19;10(*/0/1)
Conference tone  | 525@-16;2.5(.3/0/3,1/1/1)
Call waiting tone  | 425@-25,0@-25;30(.2/.2/1,.2/.2/1,0/4.4/3)

## Ireland tones

Name | ToneScript

|

Dial tone (ETSI standard)  | 425@-17;60(*/0/1)
Second dial tone  | 335@-19,425@-19;45(*/0/1+2)
Busy tone (ETSI standard)  | 425@-19; 30(0.5/0.5/1)
Reorder tone (ETSI standard)  | 425@-19; 30(.2/.2/1)
Ringback tone (same as UK, NZ etc.)  | 400@-19,450@-19;*(.4/.2/1+2,.4/.2/1+2,2/0/0)
Special information tone SIT (ETSI standard)  | 950@-16,1400@-16,1800@-16;20(.330/0/1,.330/0/2,.330/0/3,0/1/0)
MWI dial tone  | 425@-19;2(.1/.1/1);58(*/0/1)
Call forward dial tone  | 400@-16,432@-18;30(0.4/0/1,0.4/0/2)
Call waiting tone  | 425@-19;30(.3/9.7/1)
Confirm tone / routing tone  | 425@-19;1.5(0.06/0.06/1);
Prompt tone  | 335@-19,425@-19;20(*/0/1+2)

(ETSI standard) is indicated where tones are in compliance with European Telecommunications Standards Institute recommendations.

## References

## External links

* https://supportforums.cisco.com/thread/2021701

0.00

(0 votes)

Original source: https://en.wikipedia.org/wiki/ToneScript. Read more

|

Retrieved from "https://handwiki.org/wiki/index.php?title=Engineering:ToneScript&oldid=603927"